Collect (script)

Collect (script)
Category	training
Front-end	Genie
Author	Isharon

Description

This script trains outdoorsmanship and perception by using the COLLECT verb. It will run until you are mind locked in perception (the slower of the two skills).

The script cleans up after itself by KICKING each pile that you collect. If the room has too many piles to continue collecting, it will kick every pile in the room.

Instructions

Syntax

.COLLECT [ITEM]: If you just type .COLLECT with no item, the script will collect piles of torn cloth, which works in most indoor locations. If you want to collect something else, add an item. For example, if you are outdoors, try .COLLECT ROCK.

Changelog

• 2/26/2016: replaced references to $percussioninst and $percussionsong with $instrument and $playsong; included tend script; fixed possible script hangup when the room is too cluttered to find anything
• 5/23/2014: Removed instrument performance, which is no longer compatible with collecting.
• 2/6/2013: Updated for Skills 3.0.
• 8/25/2011: Added an extra pause to reduce hang-ups.

Script

put #class racial on
put #class rp on
put #class combat off
put #class joust off
action goto exit when ^You are certain you could find what you were looking for, if you had a bit more luck|^You are sure you knew what you were looking for when you started to forage|^You forage around but are unable to find anything|^You wander around and poke your fingers into a few places, wondering what you might find
setvariable COLLECT torn.cloth
if_1 setvariable COLLECT %1

send stop play
waitforre ^You stop playing your song|^In the name of love|^But you're not performing anything
send remove my $instrument
waitforre ^You slide a pair of|^You aren't wearing that|^Remove what
send put my $instrument in my $pack
waitforre ^You put your.+in your|^What were you referring to

send stand
waitforre ^You stand|^You are already standing

collect:
gosub tend
match junk The room is too cluttered to find anything here!
send collect %COLLECT
matchwait 3
send kick pile
waitforre Assuming you mean a pile|^I could not find what you were referring to|^\.\.\.wait
pause

perception.check:
if $Outdoorsmanship.LearningRate > 33 && $Perception.LearningRate > 33 then
goto endclean
else
goto collect

tend:
if $bleeding = 1 then
{
put .tend
waitfor SCRIPT DONE
}
return

junk:
send stand
waitforre ^You stand|^You are already standing
send kick pile
matchre collect I could not find what you were referring to
matchre junk Assuming you mean a pile
matchwait 1
goto junk

endclean:
send kick pile
matchre endperception I could not find what you were referring to
matchre endclean Assuming you mean a pile
matchwait 1

endperception:
send echo YOU ARE MIND LOCKED IN OUTDOORSMANSHIP AND PERCEPTION.
put #play MindLocked

exit: