Stir *KS* (script)

Stir *KS* (script)
Category	Crafting,Forging
Front-end	StormFront
Author	Kashna

What This Script Does

As long as you have all of your nuggets/ingots in the crucible, this script will do all of the smelting.

1. Started on its own, it simply smelts.
2. Started with the variable "refine" (i.e.: .Stir refine), it will grab some flux and refine the ingot.
3. Started with no variable, but flux in hand, it will verify if you wish to refine before doing so.
4. It will also clear your hands of any forging tools before stirring, and grab the ingot upon completion.

Using It For The First Time

The only part of the script that will likely require some modification is the containers that things are kept in. Currently everything is put away with the STOW verb. If you have a specific container that you keep them in, you’ll need to change these container settings. You’ll find them all in the initial part of the script, up ‘til the point where it says “StirGlance:”

Regarding Prompts

There are two kinds of prompts that you will receive within the script.

1. One is a YES/NOPE prompt. As long as you echo your text within your UI, this prompt will work perfectly by typing one of those two words. You can also NOD if you prefer.

2. The second kind of prompt is one that waits until you perform a NOD. The script is waiting for the precise phrase “You nod”, which the game produces in response to your inputting the action. This prompt is useful because if you’re missing the necessary borax flux to refine, the script will wait indefinitely until you finally do nod, giving you the time to go purchase some if necessary, while not losing your place in the script.

Stir (Script)

#Stir
goto StirGlance%1

StirPutAwayTongs:
put stow my tongs
goto StirGlance

StirPutAwayShovel:
put stow my shovel
goto StirGlance

StirPutAwayFlux:
pause 1
put stow my flux
goto StirGlance

StirPutAwayLog:
put stow my log
waitfor You put your
goto StirGlance

StirPutAwayBook:
put stow my book
waitfor You put your
goto StirGlance

StirBellows:
pause 1
put get my bellows
waitfor You get
put push my bellows
waitfor Roundtime
pause 1
put stow my bellows
goto StirCrucible

StirFuel:
pause 1
put stow my rod
put get my shov
waitfor You get
put push fuel with my shov
waitfor Roundtime
pause 1
put stow my shov
put get my stir rod
goto StirCrucible

StirGlance:
put glance
match StirPutAwayLog logbook
match StirPutAwayBook a book of
match StirPutAwayTongs tongs
match StirPutAwayShovel shovel
match StirRefineCheck borax flux
match StirGetRod at your empty
match StirCrucible stirring rod
matchwait

StirRefineCheck:
pause 1
echo
echo ***********************************
echo
echo *** Would you like to refine instead of just stir?
echo *** (YES / NOPE)  (or NOD)
echo
echo ************************************
echo
match Refine YES
match Refine Yes
match Refine YEs
match Refine yes
match Refine You nod
match StirPutAwayFlux NOPE
match StirPutAwayFlux NOpe
match StirPutAwayFlux Nope
match StirPutAwayFlux nope
matchwait

StirGlancerefine:
GetFlux:
pause 1
put get my borax flux
match PourFlux you are already
match PourFlux you get
match NoFlux what were you
matchwait

PourFlux:
pause 1
put pour flux in cruc
match StirPutAwayFlux Roundtime
match NoFlux Pour what
matchwait

NoFlux:
echo
echo *********************
echo
echo *** Need more flux
echo *** when it is acquired
echo *** and in hand NOD
echo
echo *********************
echo
waitfor You nod
goto PourFlux

StirGetRod:
put get my stir rod
match StirCrucible You get
match StirCrucible You are already
match StirOops What were you
matchwait

StirCrucible:
pause 1
put stir cruc with my rod
match StirFuel fire dies down
match StirFuel needs more fuel
match StirBellows produces less heat
match StirBellows unable to consume
match StirTurn you observe clumps
match StirDone You can only mix
match StirGetRod You must be holding
match StirGetRod With what
match StirCrucible Roundtime
matchwait


StirTurn:
pause 1
put turn cruc with my rod
waitfor Roundtime
goto StirCrucible


StirOops:
echo
echo **********************************************
echo
echo *** You don’t have the necessary tools on hand to do that
echo
echo **********************************************
echo
Exit

StirDone:
put stow my rod
put get ingot
pause 2
echo
echo *********************************************
echo
echo *** The ingot is now fully formed and ready for forging ***
echo
echo *********************************************
echo
Exit