Magical research (script)

Magical research (script)
Category	magic,training
Front-end	Genie,StormFront
Author	Padhg

This script uses Gauge Flow to train the specified magic skills.

Notes

• The script will cast Gauge Flow (GAF) at the highest multiple of 10 mana you can cast it at based on DISCERN. If you want to cast it higher or at a specific amount, just cast GAF manually before you run the script.
• You can chain magics together (from RESEARCH LIST) to research more than one topic.
• You can PERCEIVE (Moon Mages use PERCEIVE MANA) every 61 seconds to train Attunement while researching other magics, so researching STREAM is not needed.

Usage

.research <magic> ...

e.g. .research fundamental utility fundamental augmentation warding

Changelog

• 1/11/2016: Initial version

Script

if_1 goto discern
echo What would you like to research? (use RESEARCH LIST to see your options)
echo Usage: .research fundamental utility fundamental augmentation warding
goto quit

discern:
	pause
	match discern ...wait
	matchre castat100 for a total of 1\d\d streams\.
	matchre castat90 for a total of 9\d streams\.
	matchre castat80 for a total of 8\d streams\.
	matchre castat70 for a total of 7\d streams\.
	matchre castat60 for a total of 6\d streams\.
	matchre castat50 for a total of 5\d streams\.
	matchre castat40 for a total of 4\d streams\.
	matchre castat30 for a total of 3\d streams\.
	matchre castat20 for a total of 2\d streams\.
	matchre castat10 for a total of 1\d streams\.
	matchre castatmin for a total of \d streams\.
	put discern gaf
	matchwait

castat100:
	setvariable prep-mana 100
	goto research

castat90:
	setvariable prep-mana 90
	goto research

castat80:
	setvariable prep-mana 80
	goto research

castat70:
	setvariable prep-mana 70
	goto research

castat60:
	setvariable prep-mana 60
	goto research

castat50:
	setvariable prep-mana 50
	goto research

castat40:
	setvariable prep-mana 40
	goto research

castat30:
	setvariable prep-mana 30
	goto research

castat20:
	setvariable prep-mana 20
	goto research

castat10:
	setvariable prep-mana 10
	goto research

castatmin:
	setvariable prep-mana 5
	goto research

research:
	pause
	match research However, there is still more to learn
	match gaf You require some special means
	match gaf Your eyes briefly darken.
	match nextmagic Breakthrough!
	match error Usage: RESEARCH
	put research %1 300
	matchwait

nextmagic:
	shift
	if_1 goto research
	goto quit

gaf:
	put prep gaf %prep-mana
	waitfor You feel fully prepared to cast your spell.
	# wait 2 more seconds
	pause 2
	put cast
	goto research

error:
	echo %1 is not a valid research option.

quit:
	exit