See 'n Say Appraisal (script)

This is a Genie script that appraises any weapon, shield, or armor and then echoes the appraisal in an IC way. (Shorthand appraisals, such as "l/bc/f p/r very strong," are often regarded as OOC (gibberish) when gwethed or spoken in-game.)

This script is suitable for role-players, Traders (who are often asked to appraise items), and people who are simply too lazy to type or copy and paste or type from the appraisal.
For OOC appraisals, use See 'n Say Appraisal - OOC (script).

For IC comparisons, use See 'n Say Comparison (script).

Syntax

.APP %1 %2

%1: the item (use periods instead of spaces) %2: optional modifier (careful or quick)

For example, .APP MY.GREATSWORD CAREFUL, .APP HAMMER.ON.OAK.TABLE QUICK, and .APP ISHARON.SHIELD (for shown items).

Usage Notes

You do not need to type the full name of the weapon in order for it to appear in the output. The weapon name is read from the part of the appraisal that states the value.

The script should distinguish between singular and plural items when composing the output. For example, if you appraise your gauntlets, it will say, "the gauntlets are," not "the gauntlets is."

Swappable Weapons

Swappable weapons, such as bastard swords, are only partially supported by this script. If you see both appraisals when you appraise a swappable item, the script will only output the second appraisal listed. For example:

.app sword careful

A gleaming silver sword is a heavy edged melee-ranged weapon.

You are certain that it could do:
 poor puncture damage
 great slice damage
 low impact damage

You are certain that the sword is reasonably balanced and is fairly suited to gaining extra attack power from your strength.

A gleaming silver sword is a two-handed edged melee-ranged weapon.

You are certain that it could do:
 low puncture damage
 severe slice damage
 fair impact damage

You are certain that the sword is reasonably balanced and is reasonably suited to gaining extra attack power from your strength.

You are certain that the gleaming silver sword is moderately strong, and is in pristine condition.

The script would simply treat this as a two-handed edged weapon and output that appraisal.

To get around this problem, don't appraise carefully. (This makes it less likely that you will see both weapon modes.) Run the script once, swap the weapon, and then run it again. This will force it to output both appraisals.

Sample Outputs

Melee Weapon: This two-handed edged weapon can be wielded at pole range. It can inflict low puncture damage, bone-crushing slice damage, and fair impact damage. The greatsword is poorly balanced and is reasonably suited to taking advantage of the wielder's strength. It is very strong.

Thrown Weapon: This heavy thrown and heavy blunt weapon can be thrown from missile range or wielded at melee range. It can inflict no puncture damage, no slice damage, and heavy impact damage. The hammer is fairly balanced and is reasonably suited to taking advantage of the wielder's strength. It is fairly sturdy.

Brawling Weapon: These footwraps are worn while brawling to increase damage. They can inflict no puncture damage, no slice damage, and heavy impact damage. They are of average strength.

Parry Stick: This parry stick is a purely defensive item that is simply worn in combat. It is reasonably balanced and fairly sturdy.

Ranged Weapon: This long bow can be used from missile range. The longbow is well balanced and is well suited to taking advantage of the wielder's strength. It is extremely weak.

Ammunition: These bolts are ammunition for a crossbow. When fired, they can inflict heavy puncture damage, low slice damage, and low impact damage. They are somewhat flimsy.

Shield: This large shield offers fair to impressive protection at the expense of fair hindrance to one's ability to maneuver in combat. When used offensively, the shield can inflict great impact damage, is poorly balanced, and is reasonably suited to taking advantage of the user's strength. It is fairly sturdy.

Armor: This heavy plate armor offers high protection and great damage absorption for puncture attacks, great protection and great damage absorption for slice attacks, moderate protection and great damage absorption for impact attacks, good protection and high damage absorption for fire attacks, moderate protection and high damage absorption for cold attacks, and poor protection and high damage absorption for electrical attacks. This protection comes at the expense of great maneuvering hindrance and insane stealth hindrance. The armor is well constructed.

Script

send appraise %1 %2

action setvariable noun $1 when .+ the .+ (.*) (is|are|could be|might be) worth
action setvariable noun $1 when .+ the .+ (.*) (is|are|could be|might be) probably worth
action setvariable noun $1 when .+ the (.*) (is|are|could be|might be) worth
action setvariable noun $1 when .+ the (.*) (is|are|could be|might be) probably worth

action setvariable wtype $1 when .+ is a (.*) .+ weapon

action setvariable range melee when melee-ranged
action setvariable range pole when pole-ranged
action setvariable wacc am certain that when You are certain that it could do
action setvariable wacc am confident that when You are confident that it could do
action setvariable wacc think that when You think that it could do
action setvariable wacc think it is likely that when You think it is likely that it could do
action setvariable wacc believe that when You believe that it could do
action setvariable wacc am pretty sure that when You are pretty sure that it could do
action setvariable wacc estimate that when You estimate that it could do
action setvariable wacc guess that when You guess that it could do
action setvariable wacc wonder if when You wonder if it could do
action setvariable puncture $1 when ^\s+(.*) puncture damage
action setvariable slice $1 when ^\s+(.*) slice damage
action setvariable impact $1 when ^\s+(.*) impact damage
action setvariable bacc am certain that when You are certain that .+ balanced
action setvariable bacc feel certain that when You feel certain that .+ balanced
action setvariable bacc am confident that when You are confident that .+ balanced
action setvariable bacc feel confident that when You feel confident that .+ balanced
action setvariable bacc think that when You think that .+ balanced
action setvariable bacc think it is likely that when You think it is likely that .+ balanced
action setvariable bacc believe that when You believe that .+ balanced
action setvariable bacc am pretty sure that when You are pretty sure that .+ balanced
action setvariable bacc feel pretty sure that when You feel pretty sure that .+ balanced
action setvariable bacc estimate that when You estimate that .+ balanced
action setvariable bacc guess that when You guess that .+ balanced
action setvariable bacc wonder if when You wonder if .+ balanced
action setvariable balance $1 when .+ is (.*) balanced
action setvariable power $1 when .+ is (.*) suited

action setvariable stype $1 when .+ is (.*) in size
action setvariable sacc am certain that when You are certain that the .+ offers
action setvariable sacc feel certain that when You feel certain that the .+ offers
action setvariable sacc am confident that when You are confident that the .+ offers
action setvariable sacc feel confident that when You feel confident that the .+ offers
action setvariable sacc think that when You think that the .+ offers
action setvariable sacc think it is likely that when You think it is likely that the .+ offers
action setvariable sacc believe that when You believe that the .+ offers
action setvariable sacc am pretty sure that when You are pretty sure that the .+ offers
action setvariable sacc feel pretty sure that when You feel pretty sure that the .+ offers
action setvariable sacc estimate that when You estimate that the .+ offers
action setvariable sacc guess that when You guess that the .+ offers
action setvariable sacc wonder if when You wonder if the .+ offers
action setvariable sprotection $1 when .+ offers (.*) protection
action setvariable shindrance $1 when .+ it imposes a (.*) maneuvering hinde?rance
action setvariable shindrance $1 when .+ it imposes an (.*) maneuvering hinde?rance

action setvariable atype cloth when cloth armor|cloth
action setvariable atype leather when leather armor
action setvariable atype bone when bone armor
action setvariable atype light chain when light chain
action setvariable atype heavy chain when heavy chain
action setvariable atype light plate when light plate
action setvariable atype heavy plate when heavy plate
action setvariable aacc am certain that when You are certain that .+ appears? to impose
action setvariable aacc feel certain that when You feel certain that .+ appears? to impose
action setvariable aacc am confident that when You are confident that .+ appears? to impose
action setvariable aacc feel confident that when You feel confident that .+ appears? to impose
action setvariable aacc think that when You think that .+ appears? to impose
action setvariable aacc think it is likely that when You think it is likely that .+ appears? to impose
action setvariable aacc believe that when You believe that .+ appears? to impose
action setvariable aacc am pretty sure that when You are pretty sure that .+ appears? to impose
action setvariable aacc feel pretty sure that when You feel pretty sure that .+ appears? to impose
action setvariable aacc estimate that when You estimate that .+ appears? to impose
action setvariable aacc guess that when You guess that .+ appears? to impose
action setvariable aacc wonder if when You wonder if .+ appears? to impose
action setvariable apuncture $1 when .+ \s(.*) for puncture attacks
action setvariable aslice $1 when .+ \s(.*) for slice attacks
action setvariable aimpact $1 when .+ \s(.*) for impact attacks
action setvariable afire $1 when .+ \s(.*) for fire attacks
action setvariable acold $1 when .+ \s(.*) for cold attacks
action setvariable aelectrical $1 when .+ \s(.*) for electrical attacks
action setvariable ahindrance $1 when .+ appears? to impose (.*), offering

action setvariable construct $2 when ^You are certain that the .+ (is|are) (.*), and (is|are)

matchre wthrown thrown
matchre wmelee range
matchre wstick parry stick|calcified femur
matchre wbrawling brawling|elbow blades|elbow spikes|elbow wraps
matchre shield shield
matchre armor2 gauntlets|gloves|greaves|leathers|legguards|vambraces
matchre armor cloth armor|cloth|leather armor|bone armor|light chain|heavy chain|light plate|heavy plate
matchre wammob2 arrows
matchre wammoc2 bolts|quadrellos|quarrels|pulzones
matchre wammos2 bullets|clumps|lumps|rocks
matchre wammob arrow
matchre wammoc bolt|quadrello|quarrel|pulzone
matchre wammos bullet|clump|lump|rock
matchre wbow bow|sling
matchwait

wthrown:
echo This %wtype weapon can be thrown from missile range or wielded at %range range. It can inflict %puncture puncture damage, %slice slice damage, and %impact impact damage. The %noun is %balance balanced and is %power suited to taking advantage of the wielder's strength. It is %construct.

pause
goto end

wmelee:
echo This %wtype weapon can be wielded at %range range. It can inflict %puncture puncture damage, %slice slice damage, and %impact impact damage. The %noun is %balance balanced and is %power suited to taking advantage of the wielder's strength. It is %construct.

pause
goto end

wstick:
echo This parry stick is a purely defensive item that is simply worn in combat. It is %balance balanced and %construct.

pause
goto end

wbrawling:
echo These %noun are worn while brawling to increase damage. They can inflict %puncture puncture damage, %slice slice damage, and %impact impact damage. They are %construct.

pause
goto end

shield:
echo This %stype shield offers %sprotection protection at the expense of %shindrance hindrance to one's ability to maneuver in combat. When used offensively, the %noun can inflict %impact impact damage, is %balance balanced, and is %power suited to taking advantage of the user's strength. It is %construct.

pause
goto end

armor2:
echo This %atype armor offers %apuncture for puncture attacks, %aslice for slice attacks, %aimpact for impact attacks, %afire for fire attacks, %acold for cold attacks, and %aelectrical for electrical attacks. This protection comes at the expense of %ahindrance. The %noun are %construct.

pause
goto end

armor:
echo This %atype armor offers %apuncture for puncture attacks, %aslice for slice attacks, %aimpact for impact attacks, %afire for fire attacks, %acold for cold attacks, and %aelectrical for electrical attacks. This protection comes at the expense of %ahindrance. The %noun is %construct.

pause
goto end

wammob2:
echo These %noun are ammunition for a bow. When fired, they can inflict %puncture puncture damage, %slice slice damage, and %impact impact damage. They are %construct.

pause
goto end

wammoc2:
echo These %noun are ammunition for a crossbow. When fired, they can inflict %puncture puncture damage, %slice slice damage, and %impact impact damage. They are %construct.

pause
goto end

wammos2:
echo These %noun are ammunition for a sling or staff sling. When hurled, they can inflict %puncture puncture damage, %slice slice damage, and %impact impact damage. They are %construct.

pause
goto end

wammob:
echo This %noun is ammunition for a bow. When fired, it can inflict %puncture puncture damage, %slice slice damage, and %impact impact damage. It is %construct.

pause
goto end

wammoc:
echo This %noun is ammunition for a crossbow. When fired, it can inflict %puncture puncture damage, %slice slice damage, and %impact impact damage. It is %construct.

pause
goto end

wammos:
echo This %noun is ammunition for a sling or staff sling. When hurled, it can inflict %puncture puncture damage, %slice slice damage, and %impact impact damage. It is %construct.

pause
goto end

wbow:
echo This %wtype can be used from missile range. The %noun is %balance balanced and is %power suited to taking advantage of the wielder's strength. It is %construct.

pause
goto end

end: