Locate *KS* (script)

Locate *KS* (script)
Category	Moon Mage,Locate,Magic
Front-end	StormFront
Author	Kashna

What This Script Does

Casts the following 5 spells, in order. Via variables at the top of the script you determine how much mana to prepare each spell for, as well as how much to charge your perferred cambrinth device. Using the %1 and %2 variables you determine who to locate, and which spell to start the sequence at (no spell declared means it goes through all five). The spells, in order, are:

1. Clear Vision

2. Piercing Gaze

3. Focus Moonbeam

4. Locate

5. Shift Moonbeam (along with moving the moonbeam to the located individual)

If there is a pre-existing moonbeam present in the room then the script attempts to move the first one to the located individual rather than recasting Focus Moonbeam unnecessarily.

Script start examples:

• .locate Kashna - runs all spells, locating Kashna, casting moonbeam and moving the moonbeam to his location
• .locate Kashna FM - skips CV and PG casts
• .locate Kashna locate - skips CV, PG, and FM casts
• .locate Kashna SM - casts SM on the moonbeam belonging to the first moon shown via the Observe Moons verb, or the first moonbeam in the room, then attempts to move it to the first variable stated ('Kashna' in this case).

Using It For The First Time

This script makes fair use of variables.

Be sure to edit the first portion of the script to adjust the necessary variables. These include: (1) character name, (2) cambrinth item, (3) mana to prepare each spell at, (4) mana to charge your cambrinth for each spell. After initial setup these should remain constant until you've gained a significant amount of magic experience, at which point you will likely want to update the values.

Latest Update

Last Updated: 5-20-2019

• Skips SM if SM is already active on the moon mage.
• Now chooses moonbeam based on: 1st moon shown via Observe Moons verb or 1st moonbeam present in the current room.
• If moonbeam is present in the current room, skips casting Focus Moonbeam.
• Added notation for failed gesture after casting Shift Moonbeam.
• Added various moon conditions to aid in moon selection for Focus Moonbeam.

Locate (Script)

# What is the name of your Moon Mage?

setvariable MYNAME MyCharacterName

# The two variables below identify the cambrinth item you will utilize:
# CAMBDESC is the description of the item
# CAMBITEM is the item's name itself

setvariable CAMBDESC cambrinth
setvariable CAMBITEM armband

# Remove the following line if you don't need to hold cambrinth.
# There is another line at the bottom to wear it after all is completed as well.

put remove my %CAMBDESC %CAMBITEM

# Use the following set of variables to determine how much mana to prepare each spell for.
# the CAMB version determines how much mana your cambrinth item is charged for.

# Clear Vision
setvariable CVMANA 10
setvariable CVCAMB 10
# Piercing Gaze
setvariable PGMANA 10
setvariable PGCAMB 10
# Focus Moonbeam
setvariable FMMANA 10
setvariable FMCAMB 5
# Locate
setvariable LOCATEMANA 15
setvariable LOCATECAMB 5
# Shift Moonbeam
setvariable SMMANA 15
setvariable SMCAMB 5

# END VARIABLE SETTINGS  Script begins here:

LocateNote:
echo
echo ****************************
echo
echo ** First Variable: Name of person to locate
echo 
echo ** Second Variable:  Spell to Start with
echo **   Options: CV, PG, FM, Locate or SM
echo
echo ****************************
echo
pause 2
goto CheckForMoonbeam

CheckForMoonbeam:
put look
match Yavash2 red moonbeam
match Xibar2 blue moonbeam
match Katamba2 pool of black shadows
match Katamba2 pool of grey shadows
match CheckMoons Obvious paths
match CheckMoons Obvious exits
matchwait

CheckMoons:
put obs moons
match Xibar Xibar is a
match Xibar Xibar lurking
match Xibar Xibar has waned
match Xibar Xibar has nearly turned
match Xibar pulses of energy from Xibar
match Xibar Xibar's presence is on the very edge
match Xibar Xibar has nearly turned
match Xibar Xibar is a growing crescent
match Xibar Xibar forms a perfect circle
match Xibar Xibar, beginning to wane
match Xibar Xibar looks down from above
match Xibar Xibar moves across the skies
match Xibar betrays the presence of Xibar
match Xibar You sense Xibar
match Yavash Yavash is a
match Yavash Yavash lurking
match Yavash Yavash has waned
match Yavash Yavash has nearly turned
match Yavash pulses of energy from Yavash
match Yavash Yavash's presence is on the very edge
match Yavash Yavash has nearly turned
match Yavash Yavash is a growing crescent
match Yavash Yavash forms a perfect circle
match Yavash Yavash, beginning to wane
match Yavash Yavash looks down from above
match Yavash Yavash moves across the skies
match Yavash betrays the presence of Yavash
match Yavash You sense Yavash
match Katamba Katamba is a
match Katamba katamba lurking
match Katamba Katamba has waned
match Katamba Katamba has nearly turned
match Katamba pulses of energy from Katamba
match Katamba Katamba's presence is on the very edge
match Katamba Katamba has nearly turned
match Katamba Katamba is a growing crescent
match Katamba Katamba forms a perfect circle
match Katamba Katamba, beginning to wane
match Katamba Katamba looks down from above
match Katamba Katamba moves across the skies
match Katamba betrays the presence of Katamba
match Katamba You sense Katamba
match NoMoons Roundtime
matchwait

Xibar:
setvariable MOON Xibar
setvariable SKIPFM cast
goto Start%2

Xibar2:
setvariable MOON Xibar
setvariable SKIPFM skip
goto Start%2

Yavash:
setvariable MOON Yavash
setvariable SKIPFM cast
goto Start%2

Yavash2:
setvariable MOON Yavash
setvariable SKIPFM skip
goto Start%2

Katamba:
setvariable MOON Katamba
setvariable SKIPFM cast
goto Start%2

Katamba2:
setvariable MOON Katamba
setvariable SKIPFM skip
goto Start%2

NoMoons:
pause 2
echo
echo *************************
echo **  There are no moons available.
echo *************************
echo
pause 2
put .exp

Start:
StartCV:
CVCheck:
pause 1
put power %MYNAME
match PGCheck sense the Clear Vision spell
match CVPrep Roundtime
match CVCheck ...wait
matchwait

CVPrep:
pause 1
put prep cv %CVMANA
match CVPrep ...wait
match CVCharge you raise your arms
matchwait

CVCharge:
pause 1
put charg my %CAMBDESC %CAMBITEM %CVCAMB
match CVInvoke absorbs
match CVUgh strain
match CVCharge ...wait
matchwait

CVInvoke:
put invoke my %CAMBDESC %CAMBITEM 
match CVCast Roundtime
match CVInvoke ...wait
matchwait

CVCast:
waitfor fully prepared to cast your
CVCast2:
put cast
match CVCastwait ...wait
match PGCheck You gesture
match CVUgh strain
matchwait

StartPG:
PGCheck:
pause 1
put power %MYNAME
match StartFM sense the Piercing Gaze spell
match PGPrep Roundtime
match PGCheck ...wait
matchwait

PGPrep:
pause 1
put prep PG %PGMANA
match PGPrep ...wait
match PGCharge you raise your arms
matchwait

PGCharge:
pause 1
put charg my %CAMBDESC %CAMBITEM %PGCAMB
match PGInvoke absorbs
match PGUgh strain
match PGCharge ...wait
matchwait

PGInvoke:
put invoke my %CAMBDESC %CAMBITEM 
match PGCast Roundtime
match PGInvoke ...wait
matchwait

PGCast:
waitfor fully prepared to cast your
PGCast2:
put cast
match PGCastwait ...wait
match StartFM You gesture
match PGUgh strain
matchwait

StartFM:
goto StartFM%SKIPFM

StartFMcast:
FMPrep:
pause 1
put prep fm %FMMANA
match FMPrep ...wait
match FMCharge you raise your arms
matchwait

FMCharge:
pause 1
put charg my %CAMBDESC %CAMBITEM %FMCAMB
match FMInvoke absorbs
match FMUgh strain
match FMCharge ...wait
matchwait

FMInvoke:
put invoke my %CAMBDESC %CAMBITEM 
match FMCast Roundtime
match FMInvoke ...wait
matchwait

FMCast:
waitfor fully prepared to cast your
FMCast2:
put cast %MOON
match FMCastwait ...wait
match LocatePrep You gesture
match FMUgh strain
matchwait

StartFMskip:
StartLo:
StartLoc:
StartLoca:
StartLocat:
StartLocate:
LocatePrep:
pause 1
put prep locate %LOCATEMANA
match LocatePrep ...wait
match LocateCharge you raise your arms
matchwait

LocateCharge:
pause 1
put charg my %CAMBDESC %CAMBITEM %LOCATECAMB
match LocateInvoke absorbs
match LocateUgh strain
match LocateCharge ...wait
matchwait

LocateInvoke:
put invoke my %CAMBDESC %CAMBITEM 
match LocateCast Roundtime
match LocateInvoke ...wait
matchwait

LocateCast:
waitfor fully prepared to cast your
LocateCast2:
put cast %1
match LocateCastwait ...wait
match SMPrep You gesture
match LocateUgh strain
match LocateProblem location are unclear
matchwait

StartSM:
SMPrep:
pause 2
put gesture %MOON %1
match SMPrep ...wait
match MoonbeamReady sense your moonbeam move
match MoonbeamUnmoved but are unable to affect your moonbeam
match MoonbeamUnmoved unable to see your target clearly enough
match PrepareSM gesture at yourself
matchwait

PrepareSM:
pause 1
put prep SM %SMMANA
match PrepareSM ...wait
match SMCharge you raise your arms
matchwait

SMCharge:
pause 1
put charg my %CAMBDESC %CAMBITEM %SMCAMB
match SMInvoke absorbs
match SMUgh strain
match SMCharge ...wait
matchwait

SMInvoke:
put invoke my %CAMBDESC %CAMBITEM 
match SMCast Roundtime
match SMInvoke ...wait
matchwait

SMCast:
waitfor fully prepared to cast your
SMCast2:
put cast
match SMCastwait ...wait
match SMGesture You gesture
match SMUgh strain
matchwait

SMGesture:
pause 2
put gesture %MOON %1
match MoonbeamReady sense your moonbeam move
match MoonbeamUnmoved but are unable to affect your moonbeam
match MoonbeamUnmoved unable to see your target clearly enough
matchwait

SMCastWait:
pause 1
goto SMCast2

LocateCastWait:
pause 1
goto LocateCast2

CVCastwait:
pause 1
goto CVCast2

PGCastwait:
pause 1
goto PGCast2

FMCastwait:
pause 1
goto FMCast2

CVUgh:
pause 2
echo
echo ************************
echo **  Low mana - failed to cast Clear Vision
echo ************************
echo
pause 2
goto ReleaseSpell

PGUgh:
pause 2
echo
echo ************************
echo **  Low mana - failed to cast Piercing Gaze
echo ************************
echo
pause 2
goto ReleaseSpell

FMUgh:
pause 2
echo
echo ************************
echo **  Low mana - failed to cast Focus Moonbeam
echo ************************
echo
pause 2
goto ReleaseSpell

LocateUgh:
pause 2
echo
echo ************************
echo **  Low mana - failed to cast Locate.
echo ************************
echo
pause 2
goto ReleaseSpell

SMUgh:
pause 2
echo
echo ************************
echo **  Low mana - failed to cast Shift Moonbeam.
echo ************************
echo
pause 2
goto ReleaseSpell

ReleaseSpell:
put release spell
put prep cv
put invok my %CAMBDESC %CAMBITEM 
pause 2
put wear my %CAMBDESC %CAMBITEM 
waitfor fully prepared to cast your
pause 1
put cast
pause 5
goto End

LocateProblem:
MoonbeamUnmoved:
pause 2
put wear my %CAMBDESC %CAMBITEM
pause 1
echo
echo ********************************************
echo **  %MOON moonbeam cannot be moved.
echo **  %1 is too far away or not successfully located
echo ********************************************
echo
pause 5
goto End

MoonbeamReady:
pause 2
put wear my %CAMBDESC %CAMBITEM
pause 1
echo
echo ***********************************************
echo **  %MOON moonbeam has been successfully moved toward %1
echo ***********************************************
echo
pause 5
goto End

End: