Rezz (script)

Rezz (script)
Category	utility,Cleric
Front-end	Genie
Author	Tropicalo

Here are 2 rezz scripts for genie. The first is for more skilled clerics. It does not use your Osrel Meraud orb for rezzing, it just rejuvs, soul bonds, and starts infusing. The second is for clerics who still need to use Osrel Meraud. Puts rezz into the orb finds the soul before rejuving.

# ------------------------------------------------ 
# Tropicalo's Rezz script 
# Personal Version 
# ------------------------------------------------ 
# .Rezz <Person>
# ------------------------------------------------ 

Rezz:
	put #setvariable Patient %1
	gosub action.general
	gosub rejuv
	gosub mana
	gosub prep rezz
	gosub harn 15
	gosub cast
	gosub infusing
	gosub gesture %Patient
	gosub stand
	exit

Rejuv:
	gosub mana
	gosub prep rejuv 10
	gosub harn 10
	gosub cast %Patient
	if %Silver < 2 then goto rejuv
	gosub prep SB 10
	gosub harn 10
	gosub cast %Patient
	return

Infusing:
	gosub mana
	gosub harn %Harness
	gosub infuse %Infuse rezz
	if %Spirit = 1 then return
	goto infusing

action.general:
	put #setvariable Harness 20 1
	put #setvariable Infuse 20
	if_2 put #setvariable Harness %2 
	if_2 put #setvariable Infuse %2
	if_3 put #setvariable Harness %2 %3
	if_3 put #math Infuse multiply %3
	put #setvariable Silver 0
	put #setvariable Mana 0
	put #setvariable Preparedspell none
	action put #setvariable Preparedspell when You are already preparing
	action put #setvariable Preparedspell none when ^You don't have a spell prepared!|You gesture.|You reach with both|With a wave of your hand|You roll your|the spell's energies dissipate.|Invisible strands of aether roil in the air,
	action put #setvariable Mana 0 when Attunement:|you gesture|You tap into the mana|You harness some energy
	action put #setvariable Mana 1 when (?:>|\|)100%\]|You feel fully attuned to the mana streams again\.\r
	action put #setvariable Silver 0 when A thin [\S ]{3,40} nimbus surrounds \S{3,15} for a brief moment\.
	action put #math Silver add 1 when A thin silver nimbus surrounds \S{3,15}\.
	action put #setvariable Spirit 1 when the spirit of .*%Patient.* in the Void.
	action put #math Harn add -1 when You tap into the mana
	action goto abort when A shroud of vapor rises from .*%Patient.* corpse, dissipating rapidly from view.|The thin silver nimbus shrouding .*%Patient.* body fades away.
	return

Abort:
	echo *** You'll need to use an Orb on this one. ***
	exit

Mana:
	if %Mana = 1 then return
	gosub attunement
	if %Mana = 1 then return
	pause 2	
	if %Mana = 1 then return
	pause 2	
	if %Mana = 1 then return
	pause 2	
	goto mana

# ------------------------------------------------
#  Base utility labels.
# ------------------------------------------------

matchwait:
	match pause ...wait
	match pause Sorry, you may only type ahead
	match pause You can't do that while entangled in a web.
	matchwait

pause:
	pause 0.3
	goto %Return

return.p:
	pause .1
return:
	return

# ------------------------------------------------
#  Checking conditions.
# ------------------------------------------------

Attunement:
	put #setvariable Return Attunement
	match return.p Attunement:
	put mana
	goto matchwait

# ------------------------------------------------
#  Changing Conditions
# ------------------------------------------------

stand:
	if standing then return
	put #setvariable Return stand
	match stand The weight of all your possessions prevents you from standing
	match return You are already standing
	match return You stand back up
	match return You swim back up
	match stand Roundtime
	match stand you are still stunned
	put stand
	goto matchwait

# ------------------------------------------------
#  Magic labels.
# ------------------------------------------------

prep:
	if %Preparedspell = $1 then return
	gosub release
	put #setvariable Return prep
	match prep You are already preparing
	match prepared You trace an arcane sigil in the air,
	match prepared You lick the tip of your finger and trace a sigil in the air
	match prepared You raise your arms skyward, chanting
	match prepared The wailing of lost souls accompanies
	match prepared As you begin to solemnly intone the
	match prepared Your eyes darken to black as a starless
	match prepared You close your eyes and breathe deeply
	match prepared That is not a spell you can cast.
	match prepared Your skin briefly withers and tightens
	match prepared Tiny tendrils of lightning jolt
	match prepared You begin chanting a prayer to invoke the
	match prepared You are now prepared
	put prepare $0
	goto matchwait

prepared:
	put #setvariable Preparedspell $1
	return

harn:
	put #setvariable Harn 1
	if "$0" != $1 then put #setvariable Harn $2
harness:
	if %Harn < 1 then return
	put #setvariable Return harness
	match harness You tap into the mana
	match return Usage:
	match return Attunement:
	match mana You strain, but
	put harness $1
	goto matchwait

cast:
	put #setvariable Return cast
	match return.p You reach out toward 
	match return.p You gesture
	match return You don't have a spell prepared!
	match return You reach with both your hands and your
	match return With a wave of your hand
	match return I could not find what you were
	match return You roll your hands in an elliptical pattern in front of you
	match return Invisible strands of aether roil in the air, twisting into a tight braid.  
	match return Your secondary spell pattern dissipates because your target is dead, but the main spell remains intact.
	match return You can't cast
	match mana You are unable to
	put cast $0
	goto matchwait

release:
	if %Preparedspell = none then return
	put #setvariable Return release
	match return Type RELEASE HELP
	match return You aren't holding 
	match return You release 
	put release $0
	goto matchwait

gesture:
	put #setvariable Return gest
	match return you gesture.
	match return Silvery wisps trapped within the bands are channeled into the corpse.
	put gest $0
	goto matchwait

infuse:
	put #setvariable Spirit 0
	put #setvariable Return infuse
	put infuse $0
	match return roundtime
	match return You don't have enough harnessed to infuse that much.
	goto matchwait

# ------------------------------------------------ 
# Tropicalo's Rezz script 
# Old version
# ------------------------------------------------ 
# .Rezz <Person> <ammount to harness at a time> <# of times to harness per infuse>
# for exmaple if you did ".Rezz Tropicalo 5 4" it would harness 5 mana 4 times, then infuse 20 mana
# the default will harness 10 mana once, then infuse 10 mana
# ------------------------------------------------ 

if_1 goto start
	echo You must enter the name of a person to rezz
	exit

	start:
	put #setvariable Patient %1
	gosub action.general
	gosub Rezz.prep
	gosub rezz.harness
	gosub rezz.raise %Patient
	gosub stand
	gosub OM
	exit
	
action.general:
	put #setvariable Base.harn 10 1
	put #setvariable Base.infuse 10
	if_2 put #setvariable Base.harn %2 
	if_2 put #setvariable Base.infuse %2
	if_3 put #setvariable Base.harn %2 %3
	if_3 put #math Base.infuse multiply %3
	put #setvariable Paper 0
	put #setvariable Mana 0
	put #setvariable Preparedspell
	action put #setvariable POM 1 when You sense the Persistence of Mana spell upon you, which should last for (?:at least an anlas|about (?!two roisaen|three roisaen|four roisaen))
	action put #setvariable POM 0 when You reach out with your senses and
	action put #setvariable Preparedspell none when ^You don't have a spell prepared!|You gesture.|You reach with both|With a wave of your hand|You roll your|the spell's energies dissipate.|Invisible strands of aether roil in the air,
	action put #setvariable Sleep 0 when ^Your mind cannot rest while you|^You awaken from your reverie and begin
	action put #setvariable Sleep 1 when ^You relax and allow your mind|You are already resting your mind!|To wake up and start learning again, type: AWAKEN
	action put #setvariable Health 0 when You have no significant injuries. 
	action put #setvariable Health 1 when Get some healing and then try it again.|Area       Rate|You are unable to control the |in your condition.|twitching
	action put #setvariable Mana 0 when ___100%\]|you gesture|You tap into the mana|You harness some energy|A vibrant cerulean light streams from your free hand,
	action put #setvariable Mana 1 when (?:high|complete) attunement to the mana flowing through this area\.\r|You feel fully attuned to the mana streams again\.\r
	action put #setvariable Silver 0 when A thin [\S ]{3,40} nimbus surrounds \S{3,15} for a brief moment\.
	action put #setvariable Silver 1 when A thin silver nimbus surrounds \S{3,15}\.
	action put #setvariable Spirit 1 when the spirit of .*%Patient.* in the Void.
	action put #setvariable Charge 0 when as it discharges its power to aid your spell.|The .* is dim, almost magically null.
	action put #setvariable Charge 1 when Your harnessed energy dissipates.|while the rest dissipates harmlessly.
 	action put #setvariable Rope 1 when a braided bundling rope
	return


# ---

return.p:
	pause .1
return:
	return

# ---

matchwait:
	match pause ...wait
	match pause Sorry, you may only type ahead
	match pause You can't do that while entangled in a web.
	matchwait

pause:
	pause 0.3
	goto %Return

# ---

variable.set:
	put #setvariable $1 %$2
	return

# ---

stand:
	put #setvariable Return stand
	match stand The weight of all your possessions prevents you from standing
	match return You are already standing
	match return You stand back up
	match return You swim back up
	match stand Roundtime
	put stand
	goto matchwait


# ---

get:
	put #setvariable Return get
	match return.p You reach for
	match return.p you pull
	match return.p You're already holding
	match return.p You pick up
	match return.p You get
	match return.p You must unload
	match return.p You stop as you realize
	match return.p You are already holding that.
	match return.p You need a free hand
	match return.p But that is already in your inventory
	match return.p What were you referring to?
	match return.p I could not find what you were referring to.
	put get $0
	goto matchwait



# ---

put:
	put #setvariable Return Put
	match return You tuck a 
	match return You carefully socket
	match return You put your
	match return You slip
	match return You gently set
	match return Perhaps you should be holding that first.
	match return As you start to place your
	match return You reverently place
	match return There isn't any more room in the
	match return That's too heavy to go in there!
	match return I could not find what you were referring to.
	match return What were you referring to?
	put put $0
	goto matchwait

# ---

prep:
	if "%Preparedspell" = "$1" then return
	if "%Preparedspell" != "None" then gosub release
	goto prepare

release:
	put #setvariable Return release
	match return Type RELEASE HELP
	put release
	goto matchwait

prepare.rele:
	gosub release
prepare:
	put #setvariable Return prepare
	match prepare.rele You are already preparing
	match prepared You trace an arcane sigil in the air,
	match prepared You lick the tip of your finger and trace a sigil in the air
	match prepared You raise your arms skyward, chanting
	match prepared The wailing of lost souls accompanies
	match prepared As you begin to solemnly intone the
	match prepared Your eyes darken to black as a starless
	match prepared You close your eyes and breathe deeply
	match prepared That is not a spell you can cast.
	match prepared Your skin briefly withers and tightens
	match prepared Tiny tendrils of lightning jolt
	match prepared You begin chanting a prayer to invoke the
	put prepare $0
	goto matchwait

prepared:
	put #setvariable Preparedspell $1
	return

# ---

harn:
	if "$0" != "$1" then put #setvariable Nharn $2
	else put #setvariable Nharn 1
harn.check:
	if %Nharn > 0 then goto harn.count
	return

harn.count:
	put #math Nharn subtract 1
harness:
	put #setvariable Return harness
	match harn.check you tap into the
	match harn.check Usage:
	match harn.check Attunement:
	match run.like.hell You strain, but
	put harness $1
	goto matchwait

# ---

cast:
	put #setvariable Return cast
	match return You don't have a spell prepared!
	match return.p You gesture
	match return You reach with both your hands and your
	match return With a wave of your hand
	match return I could not find what you were
	match return You roll your hands in an elliptical pattern in front of you
	match return Invisible strands of aether roil in the air, twisting into a tight braid.  
	match return backfire
	match run.like.hell You are unable to
	put cast $0
	goto matchwait

# ---

gest:
	put #setvariable Return gest
	match return you gesture.
	match return Silvery wisps trapped within the bands are channeled into the corpse.
	put gest $0
	goto matchwait		


# ---
	
mana:
	put #setvariable Return mana
	if %Mana = 1 then return
	match return complete attunement
	match return fully attuned
	match return high attunement
	match return than normal
	match mana.wait Attunement:
	put mana
	goto matchwait

mana.wait:
	pause 2
	if %Mana = 1 then return
	pause 2
	if %Mana = 1 then return
	pause 2
	if %Mana = 1 then return
	pause 2
	if %Mana = 1 then return
	pause 2
	if %Mana = 1 then return
	pause 2
	if %Mana = 1 then return
	goto mana
	
# ---

Power:
	put #setvariable Return power
	match return roundtime
	match return You're in no shape to be doing that!
	match return I could not find who you were referring to.
	match return You're not ready to do that again, yet.
	put power $0
	goto matchwait

# ---

if:
	if $0
	return

# ---

Rezz.prep:
	gosub prep rezz
	waitfor you feel fully prepared
	gosub touch orb
	return

rezz.harness:
	gosub mana
	pause .2
	gosub harn %Base.harn
	put #setvariable Infuse %Base.infuse
rezz.infuse:
	put #setvariable Return rezz.infuse
	put #setvariable Spirit 0
	put infuse rezz %Infuse
	match rezz.check roundtime
	match rezz.add You don't have enough harnessed to infuse that much.
	goto matchwait

rezz.add:
	put #math Infuse add -3
	if %Infuse < 1 then goto rezz.harness
	goto rezz.infuse

rezz.check:
	pause .1
	if %Spirit = 0 then goto rezz.harness
	return

Rezz.raise:
	gosub mana
	gosub prep rejuv 10
	gosub harn 8 3
	gosub cast $0
	pause .1
	if %Silver != 1 then goto rezz.raise
	gosub prep SB
	pause 3
	gosub cast $0
	gosub gest $0
	return

# ---

OM:
	gosub mana
	gosub prep OM 10
	gosub harn 7 5
	gosub cast orb
	return

# ---

touch:
	put #setvariable Return touch
	match return.p You touch 
	match return.p injuries include...
	match return You sense a tugging sensation from the center of the orb, pulling at your consciousness.
	put touch $0
	goto matchwait