Defend (script)

From Elanthipedia
Jump to navigation Jump to search
Defend (script)
Category combat,Warrior Mage
Front-end StormFront
Author Cordath


This is the script that I use to train defenses. I've only really tested it using Warrior Mage spells, but it should work for any other guild's damage spells. AoE spells are preferable, but anything that can hit without fully targeting should work.

The script has only one parameter, which is the number of critters you want in the room. It will run in wait mode, letting critters attack you. It will check the critter count every seven seconds. When there are too many critters in the room, the script enters kill mode, where it retreats and casts the spell you specify until there are an acceptable number of critters. It will then loot the corpses and return to wait mode.

Be sure to change the variables in the script. They are:

  • wait_mode_stance: This is the stance you want to use in wait mode. Set attack to zero to take advantage of the extra 20 defense points.
  • kill_mode_stance: This is the stance you want to use in kill mode. Make sure attack is 100 and set the other points to your best defenses.
  • kill_spell: The spell you want to use in kill mode. Abbreviations are fine.
  • kill_spell_mana: The amount of mana you want to harness after prep.
  • loot_method: Type of looting to perform on dead critters. Leave it blank for the default looting method.
# Defend.cmd

#######################################################
# Edit the variables below to suit your hunting style #
#######################################################

# STANCES
#                            EVA PAR SHI ATT
setvariable wait_mode_stance 100   0 100   0
setvariable kill_mode_stance 100   0  80 100

# Put your (preferably AoE) killing spell here
setvariable kill_spell CL

# Mana to harness after prep
setvariable kill_spell_mana 7

# Type of looting to perform on dead critters
setvariable loot_method treasure

###############################
# Do not edit below this line #
###############################

echo
echo *
echo * Defense training script by Cordath Gildenmoor
echo *
if_1 goto %1
echo * USAGE: .defend <1|2|3|4>
echo *
echo * No number specified! Defaulting to one critter.
echo *

1:
on:
one:
save /(two|three|four|five|six|seven|eight|nine)/i
goto WAIT_MODE

2:
tw:
two:
save /(three|four|five|six|seven|eight|nine)/i
goto WAIT_MODE

3:
th:
thr:
thre:
three:
save /(four|five|six|seven|eight|nine)/i
goto WAIT_MODE

4:
fo:
fou:
four:
max:
save /(five|six|seven|eight|nine)/i
goto WAIT_MODE

WAIT_MODE:
echo
echo *** Entering wait mode ***
echo
put stance set %wait_mode_stance
pause 1

WAIT_MODE_COUNT:
matchre KILL_MODE %s
match WAIT_MODE_COUNT ...wait
match PAUSE Roundtime
put count critter
matchwait

PAUSE:
pause 7
goto WAIT_MODE_COUNT

KILL_MODE:
echo
echo *** Entering kill mode ***
echo
put stance set %kill_mode_stance
pause 1

PREP:
put face next
put adv
wait

RETREAT:
match RETREAT ...wait
match RETREAT unable to
match RETREAT You retreat
match PREPFIX already as far
put retreat
put retreat
put retreat
matchwait

PREPFIX:
put prep %kill_spell
put harn %kill_spell_mana
waitfor You feel fully prepared
put target
goto CAST

CAST:
match CAST ...wait
match KILL_MODE_COUNT You gesture
put cast
matchwait

KILL_MODE_COUNT:
put release
matchre PREP %s
match KILL_MODE_COUNT ...wait
match LOOT Roundtime
put count critter
matchwait

LOOT:
match LOOT ...wait
match LOOT You search
match WAIT_MODE could not find
put loot %loot_method
matchwait