YASSE Skin(script)

YASSE Skin(script)
Category	Combat
Front-end	YASSE
Author	Ithrios

Description

Skinning script that automates the skinning process. Sets your stance to a dodge and parry stance, stows any item held in your left hand, if you use a skinning knife (and set the $skinningknife$ global variable) it will stow whatever is in your right hand and wield your knife, arranges your target 0-5 times. If you enter part, bone or skin it will arrange it the number of times requested. If your a necromancer (and the global variable $class$ is set to necromancer) it will perform preserve on the corpse. If you are a necromancer and enter harvest as a variable it will perform harvest instead. Finally, when finished it will stow your skinning knife, wield your right and left hand items, loots the creature and restores your stance to its previous state (requires my Yasse Stance Script) or to a stance of 100 80 0 100.

Syntax

Syntax	Effect
.skin	Will skin the last creature slain
.skin n	Will arrange the creature n times then skin it
.skin <name>	Will arrange a dead <name> n times then skin it (Necromancers will perform preserve if a creature name is provided)
.skin second <name>	Will arrange the second dead <name> n times then skin it (Second can be substituted with the words first through sixth)
.skin bone/part/pelt	Will arrange the creature for the selected part then skin it
.skin bone/part/pelt n	Will arrange the creature for the selected part and n times total then skin it
.skin harv <name>	If your character is a necromancer it will perform harvest on <name> (Will not work if a creature name is not provided)

You can enter the above variables in any order and the script should be able to recognize them.

Updates

Last Updated: 02 May 2013 - Script Posted

Script

ifexists stance-evasion
	begin
	put stance set $stance-evasion$
	goto setup-0
	end

put stance set 100 100 0 0

setup-0:
setvariable type ""
setvariable number ""
setvariable arrange 0
setvariable all " $1$ $2$ $3$ $4$ $5$ $6$ $7$ $8$ $9$ "

setup-1:
if_1
	begin
	counter set $1$
	if $c$ > 0 goto setup-2
	shift
	goto setup-1
	end
counter set 0
goto setup-2

setup-2:	
if all contains " bone "
	begin
	setvariable type "for bone"
	calculate all remove "bone "
	end
if all contains " part "
	begin
	setvariable type "for part"
	calculate all remove "part "
	end
if all contains " skin "
	begin
	setvariable type "for skin"
	calculate all remove "skin "
	end
ifexists type
	begin
	if $c$ <= 0
		begin
		counter set 1
		end		
	end
if_c > 1
	begin
	if $class$ contains necromancer
		begin
		if_c > 5
			begin
			counter set 4
			end
		end
	if $class$ excludes necromancer
		begin
		if_c > 5
			begin
			counter set 5
			end
		end
	end
setvariable arrange $c$

if all contains " first "
	begin
	setvariable number "first"
	calculate all remove "first "
	end
if all contains " second "
	begin
	setvariable number "second"
	calculate all remove "second "
	end
if all contains " third "
	begin
	setvariable number "third"
	calculate all remove "third "
	end
if all contains " fourth "
	begin
	setvariable number "fourth"
	calculate all remove "fourth "
	end
if all contains " fifth "
	begin
	setvariable number "fifth"
	calculate all remove "fifth "
	end
if all contains " sixth "
	begin
	setvariable number "sixth"
	calculate all remove "sixth "
	end
if all contains " harv"
	begin
	if $class$ contains necromancer
		begin
		setvariable type "harvest"
		calculate all remove " harvest "
		calculate all remove " harves "
		calculate all remove " harve "
		calculate all remove " harv "
		end
	end
setvariable target $all$


lefthanditem:
setvariable lhand $lefthanditem$
if $lefthanditem$ excludes Empty
	begin
	match righthanditem you slide
	match righthanditem you sling
	match righthanditem You are already wearing that.
	match righthanditem You attach
	match lefthanditem-1 You can't wear any more
	put wear my $lefthanditem$
	end
lefthanditem-1:
if $lefthanditem$ excludes Empty
	begin
	match righthanditem you slide
	match righthanditem you sling
	match righthanditem you stow
	match righthanditem you put
	match righthanditem that's closed.
	match righthanditem There isn't any more room
	match righthanditem Stow what?
	put stow my $lefthanditem$
	matchwait
	end

righthanditem:
if x$skinningknife$x contains xx goto arrange
ifexists skinningknife goto righthanditem-1


righthanditem-1:
setvariable rhand $righthanditem$
if $righthanditem$ excludes Empty
	begin
	match skinningknife you slide
	match skinningknife you sling
	match skinningknife you stow
	match skinningknife you put
	match righthanditem-2 that's closed.
	match righthanditem-2 There isn't any more room
	match righthanditem-2 Stow what?
	put stow my $righthanditem$
	matchwait
	end

righthanditem-2:
if $righthanditem$ excludes Empty
	begin
	match skinningknife you slide
	match skinningknife you sling
	match skinningknife You are already wearing that.
	match skinningknife You attach
	match arrange You can't wear any more
	put wear my $righthanditem$
	end


skinningknife:
if x$skinningknife$x contains xx goto arrange
ifexists skinningknife 
	begin	
	match arrange you get
	match arrange already in your inventory.
	match arrange What were you referring to?
	put get $skinningknife$
	matchwait
	end

arrange:
if $class$ contains necromancer
	begin
	if harvest contains harvest
	match arrange but are unable to discern where to direct your thanatological expertise
	match arrange-1 This corpse has already been preserved
	match arrange-1 Rituals do not work upon the undead.
	match arrange-1 roundtime
	put perform preserve on $number$ $target$
	matchwait
	end
arrange-1:
if_c <= 0 goto skin
counter sub 1
match sheath already been skinned
match sheath What were you referring to?
match sheath that's not dead!
match sheath before you arrange it
match sheath Arrange what?
match sheath skin what
match skin-check Roundtime:
put arrange $number$ $target$ $type$
setvariable type ""
matchwait

skin-check:
if_c > 0 goto arrange-1
goto skin

skin:
match sheath already been skinned
match sheath What were you referring to?
match sheath roundtime
match sheath that's not dead!
match sheath before you arrange it
match sheath Arrange what?
match sheath skin what
put skin $number$ $target$
matchwait

harvest:
match arrange-1 but are unable to discern where to direct your thanatological expertise
match arrange-1 may only be performed on a creature's corpse.
match arrange-1 Rituals do not work upon the undead.
match harvest-1 roundtime
put perform harvest on $target$
matchwait

harvest-1: 
put drop mat
goto loot

errorhandler:
sheath: 
put glance
if $righthanditem$ excludes $skinningknife$ goto sheath-3
match sheath-3 You are already wearing that.
match sheath-3 You attach
match sheath-2 You can't wear any more
put wear my $skinningknife$
matchwait

sheath-2:
match sheath-3 you stow
match sheath-3 you put
match sheath-3 Stow what?
put stow my $skinningknife$
matchwait

sheath-3:
ifexists rhand goto sheath-4
goto sheath-6

sheath-4:
match sheath-6 you get
match sheath-5 already in your inventory.
match sheath-6 What were you referring to?
put get $rhand$
matchwait

sheath-5:
match sheath-6 you slide
match sheath-6 you sling
match sheath-6 you remove
match sheath-6 remove what?
match sheath-6 aren't wearing that.
put remove $rhand$
matchwait

sheath-6:
ifexists lhand goto sheath-7
goto sheath-9

sheath-7:
match sheath-9 you get
match sheath-8 already in your inventory.
match sheath-9 What were you referring to?
put get $lhand$
matchwait

sheath-8:
match sheath-9 you slide
match sheath-9 you sling
match sheath-9 you remove
match sheath-9 remove what?
match sheath-9 aren't wearing that.
put remove $lhand$
matchwait

sheath-9:
loot:
put loot
run stance